Xcas

On utilise les fonctions préprogrammées suivantes :

• int() qui renvoie la primitive d'une fonction.
• unapply() qui permet d'évaluer une expression selon un paramètre.
• solve() qui permet de résoudre une équation.
• plot() qui permet de créer et afficher un graphique.
• string() qui permet de transformer un objet (exemple : nombre entier) en une chaine de caractères.
• diff() Différenciation de la fonction.
• split((x+1)*(y-2),[x,y]) = [x+1,y-2] Séparation des variables.
• desolve() résoudre l'équation différentielle[16] (voir l'illustration).
• factor() Polynôme d'affacturage.
• nPr() calculer les permutations.
• nCr() calculer des combinaisons.
• sqrt() racine carrée.
• cross([1,2,3],[4,3,2]) = [-5,10,-5] calculer le produit croisé de deux vecteurs
• mean([3,4,2]) = 3 calculer la moyenne
• stddev([3,4,2]) = sqrt(2/3) calculer l'écart type
• variance([3,4,2]) = 2/3 calculer la variance
• det([1,2],[3,4]) = -2 calculer le déterminant d'une matrice
• extrema(-2*cos(x)-cos(x)^2,x) = [0],[pi] calculer les extrema locaux d'une fonction
• line(x=1) = la ligne verticale x=1 tracez une ligne verticale dans le système de coordonnées

Trouver plus de commandes ici : http://www-fourier.ujf-grenoble.fr/~parisse/giac/cascmd_en.pdf

On sait que la gravité terrestre nous fournit une accélération de 9,81 m s⁻², donc il suffit de l'intégrer deux fois pour avoir la position.

À la ligne 6, on remplit L avec deux solutions : une négative et une positive. On ne prendra que la solution positive, qui se trouve être la deuxième (on utilisera l'indice 1, c'est-à-dire L[1] (L'indice 0 étant la première solution)).

Code utilisé :

vitesse_chute_1_1(h):={
  local a,v,x,L,temps_chute;
  a(t):=9.81;
  v:=unapply(int(a(t),t),t);
  x:=unapply(int(v(t),t),t);
  L:=solve(x(t)=h,t);
  temps_chute:=L[1]
  retourne v(temps_chute);
}:;

On a donc ici l'appel de la fonction :

vitesse_chute_1_1(9)

Qui renvoie :

13.2883407542

Qui est bien sûr la vitesse (en m s⁻¹) que l'objet atteint au niveau du sol après une chute sans frottement d'une hauteur de 9 m.

On garde la même structure que la fonction vitesse_chute_1_1, mais on ajoute une phrase et un graphique. On met un moins devant la vitesse et la position, car l'objet tombe vers le bas, qui est considéré négatif (l'altitude étant positive vers le haut).

Code utilisé :

vitesse_chute_1_2(h):={
  local a,v,x,L,temps_chute;
  a(t):=9.81;
  v:=unapply(int(a(t),t),t);
  x:=unapply(int(v(t),t),t);
  L:=solve(x(t)=h,t);
  temps_chute:=L[1];
  title="Altitude et vitesse en fonction du temps";
  plot(-x(t),t,0,temps_chute,couleur=2+line_width_6);
  plot(-v(t),t,0,temps_chute,couleur=1+line_width_6);
  retourne "Chute de "+string(h)+" mètres : Vitesse au niveau du sol après "+string(temps_chute)+" secondes de chute : "+string(v(temps_chute))+" m.s^(-1) = "+string(v(temps_chute)*3.6)+" km.h^(-1)";
}:;

On a donc l'appel de la fonction :

vitesse_chute_1_2(9)

Qui renvoie :

Ainsi qu'un graphique :

Vitesse (rouge) et position (vert) d'un objet faisant une chute de 9 mètres sans frottement (dans une gravité terrestre).

Cette fois ci, on prend en compte la force de frottement ${\displaystyle {\overrightarrow {F_{f}}}=-k{\overrightarrow {v}}}$ : les fonctions donnant la vitesse et la position ont été calculées manuellement, grâce au principe fondamental de la dynamique.

On trouve les fonctions (du temps) suivantes :

• ${\displaystyle v_{x}(t)=\tau g(e^{-{\frac {t}{\tau }}}-1)}$
  • Avec ${\displaystyle {\begin{cases}\tau ={\frac {m}{k}}\\v(0)=0\end{cases}}}$
• ${\displaystyle x(t)=\tau ^{2}g(1-e^{-{\frac {t}{\tau }}})-\tau gt}$
  • Avec ${\displaystyle {\begin{cases}\tau ={\frac {m}{k}}\\x(0)=0\end{cases}}}$

NB : On prend ${\displaystyle k=12.4}$ en supposant que ${\displaystyle m=70}$ et que la vitesse terminale (vitesse maximale lors de la chute) de cette masses est de 200 km h⁻¹.

De plus, on ne met pas de moins devant la vitesse et la position, car le signe a déjà été pris en compte dans la réalisation des formules.

Code utilisé :

vitesse_chute_2(h):={
  local g,v,x,L,temps_chute;
  g:=9.81:;
  k:=12.4;
  m:=70:;
  v:=unapply((m*g)/k*(exp((-t)*(k/m))-1),t);
  x:=unapply(g*(m/k)^2*(1-e^((-t)*(k/m)))-(m*g*t)/k,t):;
  L:=solve(x(t)=-h,t)
  temps_chute:=L[0];
  title="Chute de 70 kg de 9 mètre : altitude (vert) et vitesse (rouge) en fonction du temps : (épais = sans frottement ; fin = avec frottements)";
  plot(v(t),t,0,temps_chute,couleur=1);
  plot(x(t),t,0,temps_chute,couleur=2);
  retourne 0;
}:;

On a donc l'appel de la fonction :

vitesse_chute_2(9)

Qui renvoie :

0

(Qui est juste présent pour vérifier que la fonction a été lue jusqu'au bout.)

Ainsi qu'un graphique :

Vitesse (rouge) et position (vert) d'un objet faisant une chute de 9 mètres avec frottement proportionnel à la vitesse (dans une gravité terrestre).

Vitesse (rouge) et position (vert) d'un objet de 70 kg faisant une chute de 9 mètres avec (trais fins) et sans (trais épais) frottement proportionnel à la vitesse, ceci dans une gravité terrestre.

On constate que les deux graphiques (avec et sans frottement) sont effectivement différents ; l'accélération n'est pas constante dans le cas du frottement : la vitesse (rouge) tend à se stabiliser (pour devenir horizontale).